LAZARUS - Animer une application avec un cycle d'images et du son

La fiche FormAnim est l’une des raisons d'être de ce tutoriel. C'est dans l'onglet de l'unité anim qu'il faut coder l'animation.

Les clauses uses de la fiche sont les suivantes :

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, ExtCtrls, Uplaysound, Process, Crt;

Afin de déterminer les valeurs du cycle des images (nombre d'exécutions, première image et dernière, il faut fixer des constantes. On les saisit sous les clauses précédentes.

const
  CNumCycles = 3; // Nombre de cycles
  CPremImg = 0; // Numéro de la première image
  CDerImg = 3; // Numéro de la dernière image

Pour réaliser le passage d'une image à l'autre et compter les répétitions du cycle, il est nécessaire de déclarer deux variables privées dans TFormAnim  : NumImg et NumCycle . Il faut aussi déclarer à ce niveau la procédure d'animation : Animation .

  private
    NumImg, NumCycle: Integer;
    procedure Animation;

Pour pouvoir appeler la fiche FormAppli à la fin de l'animation, on doit déclarer l'unité appli dans les clauses uses sous { TFormAnim } .

implementation

{$R *.lfm}

{ TFormAnim }

uses
  appli;

Pour s'assurer que le cycle, lors de l'ouverture de la fiche FormAnim , démarre bien sur la première image, on crée et renseigne sa méthode de création :

procedure TFormAnim.FormCreate(Sender: TObject);
begin
  NumImg := CPremImg - 1; // Pour bien démarrer sur la première image
end;

Dans ce tutoriel, le code de l'animation s'appuie sur trois répétitions du cycle pendant lesquelles s'affichent l'une après l'autre dans Img1 les quatre images stockées au niveau de ImgList1 . Dans ce composant, la première image du cycle porte le numéro 0 et la dernière le 3 .

Pendant l'animation, grâce à l'utilisation de Tempo1 le composant de temporisation, une image s'affiche comme préalablement paramétré toutes les 500 ms (0,5 sec.). À la fin de la troisième répétition du cycle, une annonce est dite, puis un son de transition est joué. Alors, la fiche FormAppli est créée et appelée à s'ouvrir tandis que FormAnim se ferme et que l'animation est interrompue.

L'annonce est dite grâce au composant ProcAnn qui pilote l'application de synthèse vocale espeak .

Code de la procédure d'animation :

procedure TFormAnim.Animation; // Procédure d'animation
begin
  if NumImg = CDerImg then // Dernière image ?
    begin
      NumImg := CPremImg; // Retour à la première image
      Inc(NumCycle); // Cycle suivant
      if NumCycle = CNumCycles then // cycles terminés ?
        begin
          ProcAnn.Execute;
          Tempo1.Enabled := False; // Arrêt temporisation
          FormAppli := TFormAppli.Create(FormAnim); // Création de la fiche en attente
          FormAppli.Show; // Ouverture fiche application
          FormAnim.Hide; // Fermeture fiche animation
        end;
    end
  else
    Inc(NumImg); // Image suivante;
    ImgList1.GetBitmap(NumImg, Img1.Picture.Bitmap) // Image en cours du cycle
end;

L'appel de la procédure d'animation est réalisé au niveau du timer Tempo1 qui est paramétré initialement de manière à ce qu'il soit actif dès l'ouverture de FormAnim.

procedure TFormAnim.Tempo1Timer(Sender: TObject);
begin
  Animation; // Lancement de l'animation
end;

Quant au son de transition, il est joué à l'arrêt du timer Tempo1 en fin d'animation. Afin de laisser un peu de temps pour que l'annonce vocale soit terminée avant que le son de transition soit joué, un délai d'attente de quelques secondes est nécessaire.

procedure TFormAnim.Tempo1StopTimer(Sender: TObject); // Emission du son de transition
begin
  Delay(3000); // Délai d'attente fin de diction de l'annonce
  PlaySon.Execute;
end;

La fiche FormAppli a seulement la fonction dans ce tutoriel de simuler l'application que vous voudriez voir précédée par une animation avant son ouverture. Pour l'exercice, le code est réduit à la fermeture de l'application.

C'est dans l'onglet de l'unité appli qu'il faut coder la fiche application.

Les clauses uses de la fiche sont les suivantes :

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, StdCtrls;

Une fois la fiche FormAppli ouverte suite à l'animation, pour la fermer et quitter l'application, il faut renseigner comme suit la méthode de l’événement OnCLick du bouton Quitter  :

procedure TFormAppli.Btn1Click(Sender: TObject);
begin
  Close; // Fermeture de la fiche
end;

Afin que l'application soit fermée « proprement », c'est-à-dire qu'il ne reste aucun processus en cours en arrière-plan :

procedure TFormAppli.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  Application.Terminate; // Fermeture de l'application
end;

C'est dans l'onglet de l'unité anim qu'il faut coder l'animation.

Les clauses uses de la fiche sont les suivantes :

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, ExtCtrls, MMSystem, Comobj;

Pour déterminer les valeurs du cycle des images (nombre d'exécutions, première image et dernière, il faut fixer des constantes. On les saisit sous les clauses précédentes.

const
  CNumCycles = 3; // Nombre de cycles
  CPremImg = 0; // Numéro de la première image
  CDerImg = 3; // Numéro de la dernière image

Pour réaliser le passage d'une image à l'autre et compter les répétitions du cycle, on déclare deux variables privées : NumImg et NumCycle ainsi que la procédure d'animation : Animation comme dans la méthode A1 . Mais ici, il faut aussi déclarer la procédure de l'annonce vocale.

  private
    NumImg, NumCycle: Integer;
    procedure Animation;
    procedure Annonce(const Vk: Widestring);

Pour pouvoir appeler la fiche FormAppli à la fin de l'animation, on déclare l'unité appli dans les clauses uses sous { TFormAnim } .

implementation

{$R *.lfm}

{ TFormAnim }

uses
  appli;

Pour s'assurer que le cycle lors de l'ouverture de la fiche FormAnim démarre bien sur la première image, il faut utiliser le code suivant :

procedure TFormAnim.FormCreate(Sender: TObject);
begin
  NumImg := CPremImg - 1; // Pour bien démarrer sur la première image
end;

L'animation s'appuie sur trois répétitions du cycle pendant lesquelles s'affichent l'une après l'autre dans Img1 les quatre images stockées au niveau de ImgList1 . Dans ce composant, la première image du cycle porte le numéro 0 et la dernière le 3 .

Grâce à Tempo1, le composant de temporisation, une image s'affiche comme préalablement paramétré toutes les 500 ms (0,5 sec.). À la fin de la troisième répétition du cycle, une annonce est dite puis un son de transition est joué. Alors, la fiche FormAppli est créée et appelée à s'ouvrir tandis que FormAnim se ferme et que l'animation est interrompue.

Code de la procédure d'animation :

procedure TFormAnim.Animation; // Procédure d'animation
begin
  if NumImg = CDerImg then // Dernière image ?
    begin
      NumImg := CPremImg; // Retour à la première image
      Inc(NumCycle); // Cycle suivant
      if NumCycle = CNumCycles then // cycles terminés ?
        begin
          Annonce('Bonjour et bienvenue dans notre nouvelle application'); // Diction de l'annonce vocale
          Tempo1.Enabled := False; // Arrêt temporisation
          FormAppli := TFormAppli.Create(FormAnim); // Création de la fiche en attente
          FormAppli.Show; // Ouverture fiche application
          FormAnim.Hide; // Fermeture fiche animation
        end;
    end
  else
    Inc(NumImg); // Image suivante
    ImgList1.GetBitmap(NumImg, Img1.Picture.Bitmap) // Image en cours du cycle
end;

Pour appeler la procédure d'animation, utiliser ce code :

procedure TFormAnim.Tempo1Timer(Sender: TObject);
begin
  Animation; // Lancement de l'animation
end;

Pour que l'annonce soit dite, il faut créer la procédure Annonce qui est appelée dans la partie de code concernant la procédure d'animation. Cette procédure sollicite l'interface de programmation d'application vocale (SAPI) développée par Microsoft qui permet la reconnaissance et la synthèse vocale dans les applications Windows.

Code de la procédure Annonce :

procedure TFormAnim.Annonce(const Vk: Widestring); // Procédure d'annonce vocale
var
  SavedCW: Word;
  SpVoice: Variant;
begin
  SpVoice:= CreateOleObject('SAPI.SpVoice');
  // Optionnel : Réglage vitesse et volume de la voix
  SpVoice.Rate:= 0; // Vitesse de la voix de -10 à 10
  SpVoice.Volume:= 100; // Volume de la voix de 0 à 100
  // Changer le masque d'interruption FPU pour éviter les exceptions
  SavedCW:= Get8087CW;
  try
    Set8087CW(SavedCW or $4);
    SpVoice.Speak(Vk, 0);
  finally
  // Restaurer le masque FPU
    Set8087CW(SavedCW);
  end;
end;

Quant au son de transition, il est joué lors de l'arrêt du timer Tempo1 en fin d'animation.

procedure TFormAnim.Tempo1StopTimer(Sender: TObject);
begin
  PlaySound('Son.wav',0,SND_ASYNC); // Emission du son de transition
end;

Comme stipulé précédemment, la fiche FormAppli a seulement la fonction dans ce tutoriel de simuler l'application que vous voudriez voir précédée par une animation avant son ouverture. Le code est volontairement réduit aux simples procédures de fermeture de l'application.

C'est dans l'onglet de l'unité appli que vous codez la fiche application.

Les clauses uses de la fiche sont celles-ci :

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs, StdCtrls;

Une fois la fiche FormAppli ouverte suite à l'animation, pour la fermer et quitter l'application, il faut renseigner comme suit la méthode de l’événement OnCLick du bouton Quitter  :

procedure TFormAppli.Btn1Click(Sender: TObject);
begin
  Close; // Fermeture de la fiche
end;

Pour une fermeture « propre », sans laisser de processus ouvert en arrière-plan, utilisez ce code :

procedure TFormAppli.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  Application.Terminate; // Fermeture de l'application
end;